/*
Versione Schild del buco nero di R.& N.
*/

/*
Il buco nero non ruotante ma carico in versione Schild ossia il buco nero
di Reissner-Nordström ha una struttura abbastanza semplice paragonata a
quella del buco nero anche rotante ossia il buco nero di Kerr-Newman-Schild
KNS.
*/

r:(x*x+y*y+z*z)^(1/2);

f:ratsimp(G*(2*M*r/c^2-Q^2)/r^2);

k_0:[1,x/r,y/r,z/r];

k_1:[1,-x/r,-y/r,-z/r];

/*
Qui scrivo il tensore metrico covariante usando la simbologia solita ossia
le cifre pari indicano indici generici covarianti mentre quelle dispari indicano
indici generici controvarianti. Se uso lettere alfabetiche le minuscole indicano
indici specifici covarianti ( tipicamente t,x,y,z ) mentre le maiuscole
indicano indici specifici controvarianti ( tipicamente T,X,Y,Z ).
*/

g_00:ratsimp(matrix(
[1-f*k_0[1]*k_0[1],-f*k_0[1]*k_0[2],-f*k_0[1]*k_0[3],-f*k_0[1]*k_0[4]],
[-f*k_0[2]*k_0[1],-1-f*k_0[2]*k_0[2],-f*k_0[2]*k_0[3],-f*k_0[2]*k_0[4]],
[-f*k_0[3]*k_0[1],-f*k_0[3]*k_0[2],-1-f*k_0[3]*k_0[3],-f*k_0[3]*k_0[4]],
[-f*k_0[4]*k_0[1],-f*k_0[4]*k_0[2],-f*k_0[4]*k_0[3],-1-f*k_0[4]*k_0[4]]));

/*
Questo dovrebbe essere il tensore metrico controvariante ottenuto
senza bisogno di invertire la matrice:
*/

g_11:ratsimp(matrix(
[1+f*k_1[1]*k_1[1],f*k_1[1]*k_1[2],f*k_1[1]*k_1[3],f*k_1[1]*k_1[4]],
[f*k_1[2]*k_1[1],-1+f*k_1[2]*k_1[2],f*k_1[2]*k_1[3],f*k_1[2]*k_1[4]],
[f*k_1[3]*k_1[1],f*k_1[3]*k_1[2],-1+f*k_1[3]*k_1[3],f*k_1[3]*k_1[4]],
[f*k_1[4]*k_1[1],f*k_1[4]*k_1[2],f*k_1[4]*k_1[3],-1+f*k_1[4]*k_1[4]]));

/*
Qui invece ottengo il tensore metrico controvariante invertendo esplicitamente
la matrice del tensore metrico covariante.
*/

G_11:ratsimp(invert(g_00));

/*
Dimostro che le matrici sono l'una l'inversa dell'altra
*/

ratsimp(g_00.G_11);

/*
Questa verifica è meno ovvia dato che ho ottenuto g_11 non invertendo g_00
ma usando una apposita formula...
*/

ratsimp(g_00.g_11);

/*
Ovviamente G_11 e g_11 debbono essere identiche ed infatti...
*/

ratsimp(G_11-g_11);

/*
Notare che l'uso di ratsimp(...) non ha pure ragioni estetiche ma
ho constatato che è indispensabile semplificare i risultati dei
calcoli eseguiti...
ORA, noti i tensori metrici sia covariante che controvariante
bisognerebbe ... farne uso ossia calcolare i simboli di Christoffel,
il tensore di Riemann e quello di Ricci...
COL TEMPO... ;-) 
*/